ASP 에서 RSS 내용 퍼오기

네이버 어디선가 검색해서 찾은것 같은데 출처를 모르겠음.
그것을 조금 수정해서 사용한 것임.

<%
 'RSS 시간대 한국시간으로 변경(Start)
 Function UTCtoDate(ByVal value)
  
  Dim temp : temp = split(value,",")  ' 요일 분리
  Dim temp2 : temp2 = split(temp(1),"+") ' 표준시간대 분리
  
  Dim minspan       ' 표준시간대 분리된 값을 가지고 분으로 계산
  minspan = CInt(right(trim(temp2(1)),2)) + (60 * CInt(left(trim(temp2(1)),2)))
  
  Dim returnDate      ' 기준시각을 한국시간으로 맞춰서 보이게함
  returnDate = DateAdd("s",  (540 * 60) - (minspan*60) ,temp2(0))    
  
  UTCtoDate = returnDate
  
 End Function
 'RSS 시간대 한국시간으로 변경(End)

 'RSS XML 퍼오기(Start)
 Dim xmlHttp
 Set xmlHttp = Server.CreateObject("MSXML2.XMLHTTP.3.0")
 xmlHttp.Open "Get", "RSS주소URL", false    'Rss URL 을 입력한다
 xmlHttp.Send()

 Dim RSSXML
 RSSXML = xmlHttp.ResponseText

 Dim xmlDOM
 Set xmlDOM = Server.CreateObject("MSXML2.DomDocument.3.0")
 xmlDOM.async = false
 xmlDOM.LoadXml(RSSXML)

 Set xmlHttp = Nothing

 Dim RSSItems
 Set RSSItems = xmlDOM.getElementsByTagName("item")
 Set xmlDOM = Nothing

 Dim RSSItemsCount   
 RSSItemsCount = RSSItems.Length-1

 Dim i, RSSItem, child, Item, num

 'Dim item() '배열선언
 ReDim item(RSSItemsCount,3)

 For i = 0 To RssItemsCount
  
  Set RSSItem = RSSItems.Item(i)

  for each child in RSSItem.childNodes ' Rss의 Item 항목 추출/저장
   Select case lcase(child.nodeName)
    case "title"    '//글 제목
     Item(i,0) = child.text
    case "link"    '//글 URL
     Item(i,1) = child.text
    case "pubdate"   '//글 작성일
     Item(i,2) = Left(UTCtoDate(child.text),10)
    case "description"    '//글 내용
     Item(i,3) = child.text
'//case 에 추가하면 RSS에서 다른 것도 퍼올 수 있다.
   End Select
  Next
 Next

 'RSS XML 퍼오기(End)
%>   
<table border="0">
          <tr>
            <th>No.</th>
            <th>제목(링크)</th>
            <th>날자</th>
            <th>상태</th>
          </tr>
<%
  for i = 0 to UBound(Item)
   num = RSSItemsCount + 1 - i
%>
          <tr>
            <td><%=num%></td>
            <td><a href="<%=Item(i,1)%>" target="_blank"><%=Item(i,0)%></a></td>
            <td><%=Item(i,2)%></td>
            <td>등록</td>
          </tr>
<%
  Next
%>
</table>